mirror of
https://github.com/wahyd4/gitlabhq.git
synced 2026-08-15 23:56:09 +10:00
Dmitriy Zaporozhets
d01d0c02b7
Signed-off-by: Dmitriy Zaporozhets <dmitriy.zaporozhets@gmail.com> Conflicts: app/controllers/admin/application_settings_controller.rb app/controllers/groups/group_members_controller.rb app/controllers/projects/deploy_keys_controller.rb app/controllers/projects/project_members_controller.rb app/models/concerns/mentionable.rb app/models/project.rb app/models/project_team.rb app/models/service.rb app/views/admin/application_settings/_form.html.haml app/views/admin/groups/show.html.haml app/views/groups/group_members/_new_group_member.html.haml config/initializers/1_settings.rb db/schema.rb lib/gitlab/reference_extractor.rb spec/lib/gitlab/reference_extractor_spec.rb
120 lines
3.4 KiB
CoffeeScript
120 lines
3.4 KiB
CoffeeScript
class @UsersSelect
|
|
constructor: ->
|
|
@usersPath = "/autocomplete/users.json"
|
|
@userPath = "/autocomplete/users/:id.json"
|
|
|
|
$('.ajax-users-select').each (i, select) =>
|
|
@skipLdap = $(select).hasClass('skip_ldap')
|
|
@projectId = $(select).data('project-id')
|
|
@groupId = $(select).data('group-id')
|
|
showNullUser = $(select).data('null-user')
|
|
showAnyUser = $(select).data('any-user')
|
|
showEmailUser = $(select).data('email-user')
|
|
firstUser = $(select).data('first-user')
|
|
|
|
$(select).select2
|
|
placeholder: "Search for a user"
|
|
multiple: $(select).hasClass('multiselect')
|
|
minimumInputLength: 0
|
|
query: (query) =>
|
|
@users query.term, (users) =>
|
|
data = { results: users }
|
|
|
|
if query.term.length == 0
|
|
if firstUser
|
|
# Move current user to the front of the list
|
|
for obj, index in data.results
|
|
if obj.username == firstUser
|
|
data.results.splice(index, 1)
|
|
data.results.unshift(obj)
|
|
break
|
|
|
|
if showNullUser
|
|
nullUser = {
|
|
name: 'Unassigned',
|
|
avatar: null,
|
|
username: 'none',
|
|
id: 0
|
|
}
|
|
data.results.unshift(nullUser)
|
|
|
|
if showAnyUser
|
|
anyUser = {
|
|
name: 'Any',
|
|
avatar: null,
|
|
username: 'none',
|
|
id: null
|
|
}
|
|
data.results.unshift(anyUser)
|
|
|
|
if showEmailUser && data.results.length == 0 && query.term.match(/^[^@]+@[^@]+$/)
|
|
emailUser = {
|
|
name: "Invite \"#{query.term}\"",
|
|
avatar: null,
|
|
username: query.term,
|
|
id: query.term
|
|
}
|
|
data.results.unshift(emailUser)
|
|
|
|
query.callback(data)
|
|
|
|
initSelection: (element, callback) =>
|
|
id = $(element).val()
|
|
if id != "" && id != "0"
|
|
@user(id, callback)
|
|
|
|
formatResult: (args...) =>
|
|
@formatResult(args...)
|
|
formatSelection: (args...) =>
|
|
@formatSelection(args...)
|
|
dropdownCssClass: "ajax-users-dropdown"
|
|
escapeMarkup: (m) -> # we do not want to escape markup since we are displaying html in results
|
|
m
|
|
|
|
formatResult: (user) ->
|
|
if user.avatar_url
|
|
avatar = user.avatar_url
|
|
else
|
|
avatar = gon.default_avatar_url
|
|
|
|
"<div class='user-result'>
|
|
<div class='user-image'><img class='avatar s24' src='#{avatar}'></div>
|
|
<div class='user-name'>#{user.name}</div>
|
|
<div class='user-username'>#{user.username}</div>
|
|
</div>"
|
|
|
|
formatSelection: (user) ->
|
|
user.name
|
|
|
|
user: (user_id, callback) =>
|
|
url = @buildUrl(@userPath)
|
|
url = url.replace(':id', user_id)
|
|
|
|
$.ajax(
|
|
url: url
|
|
dataType: "json"
|
|
).done (user) ->
|
|
callback(user)
|
|
|
|
# Return users list. Filtered by query
|
|
# Only active users retrieved
|
|
users: (query, callback) =>
|
|
url = @buildUrl(@usersPath)
|
|
|
|
$.ajax(
|
|
url: url
|
|
data:
|
|
search: query
|
|
per_page: 20
|
|
active: true
|
|
project_id: @projectId
|
|
group_id: @groupId
|
|
skip_ldap: @skipLdap
|
|
dataType: "json"
|
|
).done (users) ->
|
|
callback(users)
|
|
|
|
buildUrl: (url) ->
|
|
url = gon.relative_url_root + url if gon.relative_url_root?
|
|
return url
|